ParseGen grammar for the subset of Scheme used by nboyer.sch.

This grammar is adequate for a parser benchmark, and that's all.

*terminals

id
boolean
number
character
string
lparen
rparen
vecstart
quote
backquote
comma
splicing
period

*productions

<datum>           ::=  <simple-datum>                           #identity
                  ::=  <compound-datum>                         #identity
<simple-datum>    ::=  boolean                                  #makeBool
                  ::=  number                                   #makeNum
                  ::=  character                                #makeChar
                  ::=  string                                   #makeString
                  ::=  <symbol>                                 #identity
<symbol>          ::=  id                                       #makeSym
<compound-datum>  ::=  <list>                                   #identity
                  ::=  <vector>                                 #identity
<list>            ::=  lparen <list2>                           #identity
                  ::=  <abbreviation>                           #identity
<list2>           ::=  rparen                                   #emptyList
                  ::=  <datum> <list3>                          #cons
<list3>           ::=  <data> <list4>                           #pseudoAppend
<list4>           ::=  rparen                                   #emptyList
                  ::=  period <datum> rparen                    #identity

<abbreviation>    ::=  <abbrev-prefix> <datum>                  #list
<abbrev-prefix>   ::=  quote                                    #symQuote
                  ::=  backquote                                #symBackquote
                  ::=  comma                                    #symUnquote
                  ::=  splicing                                 #symSplicing
<vector>          ::=  vecstart <data> rparen                   #list2vector

<data>            ::=                                           #emptyList
                  ::=  <datum> <data>                           #cons

*end